***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jul 2, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJD55N04S-AU     drain  gate  source
Lg     gate   g1   2.2n
Ld     drain  d1   100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     0.9882
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=202.7  VTO=2.26  LEVEL=3  VMAX=1.2e5  ETA=0  gamma=1.05 nfs=8.052e+11)
Rd     d1    d2    3.8m TC=4.7m,10u
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=44     TBV1=5.617e-4   TBV2=-2.3e-7  CJO=1.207e-9  M=1.324  VJ=1.055e+1)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=5.294e-11  N=1.142  RS=0.04u  EG=1.160  TT=30n  ikf=6.547e+1)
Rdiode  d1  21    2.864e-3 TC=3m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   2.715e-10
.MODEL     DGD    D(M=1.508   CJO=2.715e-10   VJ=6.930)
Rpar      b    d2   1Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    1.11275e-9
.ENDS
*$
